git-codeowners/flake.nix at main · triarius/git-codeowners · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
{
  description = "A modern Rust project environment using Nix and Crane";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    crane.url = "github:ipetkov/crane";
    systems.url = "github:nix-systems/default";
  };

  outputs =
    {
      self,
      nixpkgs,
      crane,
      systems,
      ...
    }:
    let
      forEachSystem =
        f:
        nixpkgs.lib.genAttrs (import systems) (
          system:
          f rec {
            pkgs = import nixpkgs { inherit system; };
            craneLib = crane.mkLib pkgs;
            src =
              let
                fixturesFilter = path: _type: builtins.match ".*/examples/.*" path != null;
                fixturesOrCargo = path: type: (fixturesFilter path type) || (craneLib.filterCargoSources path type);
              in
              pkgs.lib.cleanSourceWith {
                src = craneLib.path ./.;
                filter = fixturesOrCargo;
              };
          }
        );
    in
    {
      packages = forEachSystem (
        {
          pkgs,
          craneLib,
          src,
        }:
        let
          commonArgs = {
            inherit src;
            strictDeps = true;
            nativeBuildInputs = [ pkgs.pkg-config ];
            buildInputs = [ pkgs.openssl ];
          };

          # Build *only* the dependencies to cache them in the Nix store
          cargoArtifacts = craneLib.buildDepsOnly commonArgs;
        in
        {
          default = craneLib.buildPackage (
            commonArgs
            // {
              inherit cargoArtifacts;
            }
          );
        }
      );

      devShells = forEachSystem (
        {
          pkgs,
          craneLib,
          ...
        }:
        {
          default = craneLib.devShell {
            inputsFrom = [ self.packages.${pkgs.system}.default ];
            packages = with pkgs; [
              cargo
              rustc
              rust-analyzer
              rustfmt
              clippy
            ];
            env = {
              RUST_SRC_PATH = "${pkgs.rustPlatform.rustLibSrc}";
              RUST_BACKTRACE = "1";
            };
          };
        }
      );
    };
}